graphicsmagick in perl shrink image to size

Question

The graphicsmagick package for perl is very extensive but the documentation appears light (or confusing to me) If I have an image and I want to ensure the size is within 800x200 (like https://via.placeholder.com/800x200) while maintaining the aspect ratio of the image, which commands should I use?

In php I have

$tmpImageFile->scaleImage(100,0);
$imageGeometry = $tmpImageFile->getImageGeometry();
$imageHeight = $imageGeometry['height'];
if ( $imageHeight > 100 ) {
    $tmpImageFile->scaleImage(0,100);
}

Answer 1

Maybe you could do something like this:

use feature qw(say);
use strict;
use warnings;
use Graphics::Magick;

my $img = Graphics::Magick->new;
$img->ReadImage('gm.png');
my $height = $img->Get('height');
my $width = $img->Get('width');
say "Height = ", $img->Get('height');
say "Width = ", $img->Get('width');
my $target_width = 800;
my $target_height = 200;
my $factor1 = $target_width/$width;
my $factor2 = $target_height/$height;
say "factor1 = $factor1";
say "factor2 = $factor2";
say "$width x $factor1 = ", $width * $factor1;
my $height1 = $height * $factor1;
say "$height x $factor1 = ", $height1;
my $width2 = $width * $factor2;
say "$width x $factor2 = ", $width2;
say "$height x $factor2 = ", $height * $factor2;
$target_height = $height1 if $height1 < $target_height;
$target_width = $width2 if $width2 < $target_width;
$img->Scale(height => $target_height, width => $target_width);
say "Height = ", $img->Get('height');
say "Width = ", $img->Get('width');
$img->Write('out.jpg');

Here I have created an input image "gm.png" :

When running the script I get output:

Height = 404
Width = 1548
factor1 = 0.516795865633075
factor2 = 0.495049504950495
1548 x 0.516795865633075 = 800
404 x 0.516795865633075 = 208.785529715762
1548 x 0.495049504950495 = 766.336633663366
404 x 0.495049504950495 = 200
Height = 200
Width = 766

And the saved output file out.jpg:

Answer 2

The algorithm of a solution for the problem is quite simple.

It is required to find the smallest scale for the image between scale for width and height. Once scale identified apply it to the image.

use strict;
use warnings;

use Graphics::Magick;

my $fname = shift || die "Provide filename";

my($image,$img);
my($scale,$scaleH,$scaleW);

my $holder = {
                width   => 800,
                height  => 200
            };

$image = Graphics::Magick->new;
$image->ReadImage($fname);

$img->{height}  = $image->Get('height');
$img->{width}   = $image->Get('width');

$scaleH = $holder->{height} / $img->{height};
$scaleW = $holder->{width}  / $img->{width};
$scale  = $scaleH < $scaleW ? $scaleH : $scaleW;

$image->Scale( height => $img->{height}*$scale, width => $img->{width}*$scale );
$image->write('image_new.jpg');

exit 0;

For a test was taken a random file from internet

Result verification

$ file image.png
image.png: PNG image data, 2250 x 585, 8-bit/color RGB, non-interlaced

$ file image_new.jpg
image_new.jpg: JPEG image data, JFIF standard 1.01, resolution (DPI), density 72x72, segment length 16, baseline, precision 8, 769x200, components 3