How to program in Prolog a function that does operations on lists

Question

How can I make a program in Prolog that contains n numbers of a and n numbers of b, it's important to note here that the number of a and b in the list must be equal, also the list must always start with a and finish with b, otherwise it's false. Example : [a,b] is true, [a,a,a,b,b,b] is true, [a,a,a,a] is false and [a,a,a,b,b] is also false.

Here is what I tried to do :

langageB([b]).
langageB([b| S]):- langageB(S).

language([]).

langage([a,b]).
langage([a | S]):- langage(S).
langage([a| S]):- langageB(S).

But it does not work as I want it to.

Answer 1

Using DCG notation, the desired language can be defined as:

langage --> [a,b].
langage --> [a], langage, [b]. % For each a at the beginning of the list 
                               % there must be a corresponding b at the end

langage(List) :- phrase(langage, List).

Examples:

?- langage([a,a,a,b,b,b]).
true .

?- langage([a,a,b,b,b]).
false.

?- langage(L).
L = [a, b] ;
L = [a, a, b, b] ;
L = [a, a, a, b, b, b] ;
L = [a, a, a, a, b, b, b, b] .

If you want to see how to define the predicate directly using difference lists, you can list the clauses of the predicate langage/2:

?- listing(langage).

langage([a, b|A], A).

langage([a|A], B) :-
    langage(A, C),
    C=[b|B].

So, an alternative solution is:

langage(List) :-
  langage(List, []).

langage([a, b|A], A).

langage([a|A], B) :-
    langage(A, C),
    C = [b|B].

Answer 2

Assuming e.g. [a, b, a, b] is an acceptable list:

go :-
    findnsols(20, ABs, ab_list(ABs), ABsLst), !,
    writeln(ABsLst).


ab_list(ABsWrapped) :-
    length(ABs, Len),
    ab_list_(Len, 0, [], ABs),
    append([[a], ABs, [b]], ABsWrapped).


ab_list_(0, 0, ABs, ABs) :- !.

ab_list_(CharsToAdd, Bal, SoFar, ABs) :-
    succ(CharsToAdd0, CharsToAdd),
    add_char(Char, Inc),
    Bal1 is Bal + Inc,
    % Ensure that the balance can be zero for the complete list
    CharsToAdd0 >= abs(Bal1),
    ab_list_(CharsToAdd0, Bal1, [Char|SoFar], ABs).

add_char(b, -1).
add_char(a, 1).

Results:

?- time(go).
[[a,b],[a,a,b,b],[a,b,a,b],[a,a,a,b,b,b],[a,a,b,a,b,b],[a,b,a,a,b,b],[a,a,b,b,a,b],[a,b,a,b,a,b],[a,b,b,a,a,b],[a,a,a,a,b,b,b,b],[a,a,a,b,a,b,b,b],[a,a,b,a,a,b,b,b],[a,b,a,a,a,b,b,b],[a,a,a,b,b,a,b,b],[a,a,b,a,b,a,b,b],[a,b,a,a,b,a,b,b],[a,a,b,b,a,a,b,b],[a,b,a,b,a,a,b,b],[a,b,b,a,a,a,b,b],[a,a,a,b,b,b,a,b]]
    % 935 inferences, 0.001 CPU in 0.001 seconds (100% CPU, 1419728 Lips)

Original: Here's a (very inefficient) solution as a one-liner in swi-prolog:

length(As, 2), same_length(As, Bs), maplist(=(a), As), maplist(=(b), Bs), append([As, Bs], ABs), distinct(ABsPerm, permutation(ABs, ABsPerm)), append([[a], ABsPerm, [b]], Final).

Answer 3

langage --> [a], ( [] | langage ) , [b].

?- phrase(langage, Xs).
   Xs = "ab"
;  Xs = "aabb"
;  Xs = "aaabbb"
;  Xs = "aaaabbbb"
;  Xs = "aaaaabbbbb"
;  ... .