vb.net autocad get blockreference winform

Question

i use vb.net To dev winform app. I can take blockreference, block name"Tab1". Now i want Get this block To edit block attribute, but i don't know how to do that,i search on gg but have no result.

Dim appProgID As String = "Autocad.Application"
Dim fname As String = "C:\Users\Kid\Downloads\IDEA FOR TOOL\TEST\TABLE ATTRIBUTE.dwg"

Dim AcadType As Type = Type.GetTypeFromProgID(appProgID)


Dim AcadApp As Object = Activator.CreateInstance(AcadType)
Dim visargs() As Object = New Object(0) {}
visargs(0) = False
 AcadApp.GetType().InvokeMember("Visible", BindingFlags.SetProperty, Nothing, AcadApp, visargs, Nothing)
Dim AcadDocs As Object = AcadApp.GetType().InvokeMember(
"Documents", BindingFlags.GetProperty, Nothing, AcadApp, Nothing)


Dim args() As Object = New Object(1) {}
args(0) = fname
args(1) = False

 Dim AcDoc As Object = AcadDocs.GetType.InvokeMember(
    "Open", BindingFlags.InvokeMethod, Nothing, AcadDocs, args, Nothing)

AcadApp.GetType.InvokeMember(
    "ActiveDocument", BindingFlags.GetProperty, Nothing, AcadApp, Nothing, Nothing)

 AcDoc = AcadApp.GetType.InvokeMember(
"ActiveDocument", BindingFlags.GetProperty, Nothing, AcadApp, Nothing, Nothing)


Dim AcadModel As Object = AcDoc.GetType.InvokeMember("modelspace", BindingFlags.GetProperty, Nothing, AcDoc, Nothing)
Dim entity As Object
For Each entity In AcadModel
If TypeName(entity) = "IAcadBlockReference" Then
'here i want to take this block has name "tab1"       
End If
Next

Answer 1

You don't need to use InvokeMember, VB.NET supports late binding.

Dim acadType As Type = Type.GetTypeFromProgID("AutoCAD.Application")
Dim acadApp = Activator.CreateInstance(acadType)
acadApp.Visible = true
Dim doc = acadApp.Documents.Open("C:\Users\Kid\Downloads\IDEA FOR TOOL\TEST\TABLE ATTRIBUTE.dwg")
Dim entity
For Each entity In doc.ModelSpace
  If entity.ObjectName = "AcDbBlockReference" AndAlso _
    String.Equals(entity.Name, "Tab1", StringComparison.OrdinalIgnoreCase) Then
    Dim att
    For Each att In entity.GetAttributes()
      If att.TagString = "A" Then
        att.TextString = "Your value"
      End If
    Next          
  End If
Next

If you want to have autocompletion, you need to download the ObjectARX SDK and add the following COM references to your VS project:

1. C:\ObjectARX 20..\inc-x64\Autodesk.AutoCAD.Interop.dll
2. C:\ObjectARX 20..\inc-x64\Autodesk.AutoCAD.Interop.Common.dll

Then you will be able to use typed variables like this:

Dim acadApp As AcadApplication = Activator.CreateInstance(acadType)